%
% (c) The University of Glasgow 2006
% (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
%
\section[TcExpr]{Typecheck an expression}
\begin{code}
module TcExpr ( tcPolyExpr, tcPolyExprNC, tcMonoExpr, tcMonoExprNC,
tcInferRho, tcInferRhoNC,
tcSyntaxOp, tcCheckId,
addExprErrCtxt ) where
#include "HsVersions.h"
#ifdef GHCI /* Only if bootstrapped */
import TcSplice( tcSpliceExpr, tcBracket )
import qualified DsMeta
#endif
import HsSyn
import TcHsSyn
import TcRnMonad
import TcUnify
import BasicTypes
import Inst
import TcBinds
import TcEnv
import TcArrows
import TcMatches
import TcHsType
import TcPat
import TcMType
import TcType
import Id
import DataCon
import Name
import TyCon
import Type
import Coercion
import Var
import VarSet
import TysWiredIn
import TysPrim( intPrimTy )
import PrimOp( tagToEnumKey )
import PrelNames
import DynFlags
import SrcLoc
import Util
import ListSetOps
import Maybes
import Outputable
import FastString
import Control.Monad
\end{code}
%************************************************************************
%* *
\subsection{Main wrappers}
%* *
%************************************************************************
\begin{code}
tcPolyExpr, tcPolyExprNC
:: LHsExpr Name
-> TcSigmaType
-> TcM (LHsExpr TcId)
tcPolyExpr expr res_ty
= addExprErrCtxt expr $
do { traceTc "tcPolyExpr" (ppr res_ty); tcPolyExprNC expr res_ty }
tcPolyExprNC expr res_ty
= do { traceTc "tcPolyExprNC" (ppr res_ty)
; (gen_fn, expr') <- tcGen GenSigCtxt res_ty $ \ _ rho ->
tcMonoExprNC expr rho
; return (mkLHsWrap gen_fn expr') }
tcMonoExpr, tcMonoExprNC
:: LHsExpr Name
-> TcRhoType
-> TcM (LHsExpr TcId)
tcMonoExpr expr res_ty
= addErrCtxt (exprCtxt expr) $
tcMonoExprNC expr res_ty
tcMonoExprNC (L loc expr) res_ty
= ASSERT( not (isSigmaTy res_ty) )
setSrcSpan loc $
do { expr' <- tcExpr expr res_ty
; return (L loc expr') }
tcInferRho, tcInferRhoNC :: LHsExpr Name -> TcM (LHsExpr TcId, TcRhoType)
tcInferRho expr = addErrCtxt (exprCtxt expr) (tcInferRhoNC expr)
tcInferRhoNC (L loc expr)
= setSrcSpan loc $
do { (expr', rho) <- tcInfExpr expr
; return (L loc expr', rho) }
tcInfExpr :: HsExpr Name -> TcM (HsExpr TcId, TcRhoType)
tcInfExpr (HsVar f) = tcInferId f
tcInfExpr (HsPar e) = do { (e', ty) <- tcInferRhoNC e
; return (HsPar e', ty) }
tcInfExpr (HsApp e1 e2) = tcInferApp e1 [e2]
tcInfExpr e = tcInfer (tcExpr e)
\end{code}
%************************************************************************
%* *
tcExpr: the main expression typechecker
%* *
%************************************************************************
\begin{code}
tcExpr :: HsExpr Name -> TcRhoType -> TcM (HsExpr TcId)
tcExpr e res_ty | debugIsOn && isSigmaTy res_ty
= pprPanic "tcExpr: sigma" (ppr res_ty $$ ppr e)
tcExpr (HsVar name) res_ty = tcCheckId name res_ty
tcExpr (HsApp e1 e2) res_ty = tcApp e1 [e2] res_ty
tcExpr (HsLit lit) res_ty = do { let lit_ty = hsLitType lit
; tcWrapResult (HsLit lit) lit_ty res_ty }
tcExpr (HsPar expr) res_ty = do { expr' <- tcMonoExprNC expr res_ty
; return (HsPar expr') }
tcExpr (HsSCC lbl expr) res_ty
= do { expr' <- tcMonoExpr expr res_ty
; return (HsSCC lbl expr') }
tcExpr (HsTickPragma info expr) res_ty
= do { expr' <- tcMonoExpr expr res_ty
; return (HsTickPragma info expr') }
tcExpr (HsCoreAnn lbl expr) res_ty
= do { expr' <- tcMonoExpr expr res_ty
; return (HsCoreAnn lbl expr') }
tcExpr (HsOverLit lit) res_ty
= do { lit' <- newOverloadedLit (LiteralOrigin lit) lit res_ty
; return (HsOverLit lit') }
tcExpr (NegApp expr neg_expr) res_ty
= do { neg_expr' <- tcSyntaxOp NegateOrigin neg_expr
(mkFunTy res_ty res_ty)
; expr' <- tcMonoExpr expr res_ty
; return (NegApp expr' neg_expr') }
tcExpr (HsIPVar ip) res_ty
= do { let origin = IPOccOrigin ip
; ip_ty <- newFlexiTyVarTy argTypeKind
; ip_var <- emitWanted origin (mkIPPred ip ip_ty)
; tcWrapResult (HsIPVar (IPName ip_var)) ip_ty res_ty }
tcExpr (HsLam match) res_ty
= do { (co_fn, match') <- tcMatchLambda match res_ty
; return (mkHsWrap co_fn (HsLam match')) }
tcExpr (ExprWithTySig expr sig_ty) res_ty
= do { sig_tc_ty <- tcHsSigType ExprSigCtxt sig_ty
; (gen_fn, expr')
<- tcGen ExprSigCtxt sig_tc_ty $ \ skol_tvs res_ty ->
tcExtendTyVarEnv2 (hsExplicitTvs sig_ty `zip` mkTyVarTys skol_tvs) $
tcMonoExprNC expr res_ty
; let inner_expr = ExprWithTySigOut (mkLHsWrap gen_fn expr') sig_ty
; (inst_wrap, rho) <- deeplyInstantiate ExprSigOrigin sig_tc_ty
; tcWrapResult (mkHsWrap inst_wrap inner_expr) rho res_ty }
tcExpr (HsType ty) _
= failWithTc (text "Can't handle type argument:" <+> ppr ty)
\end{code}
%************************************************************************
%* *
Infix operators and sections
%* *
%************************************************************************
Note [Left sections]
~~~~~~~~~~~~~~~~~~~~
Left sections, like (4 *), are equivalent to
\ x -> (*) 4 x,
or, if PostfixOperators is enabled, just
(*) 4
With PostfixOperators we don't actually require the function to take
two arguments at all. For example, (x `not`) means (not x); you get
postfix operators! Not Haskell 98, but it's less work and kind of
useful.
Note [Typing rule for ($)]
~~~~~~~~~~~~~~~~~~~~~~~~~~
People write
runST $ blah
so much, where
runST :: (forall s. ST s a) -> a
that I have finally given in and written a special type-checking
rule just for saturated appliations of ($).
* Infer the type of the first argument
* Decompose it; should be of form (arg2_ty -> res_ty),
where arg2_ty might be a polytype
* Use arg2_ty to typecheck arg2
Note [Typing rule for seq]
~~~~~~~~~~~~~~~~~~~~~~~~~~
We want to allow
x `seq` (# p,q #)
which suggests this type for seq:
seq :: forall (a:*) (b:??). a -> b -> b,
with (b:??) meaning that be can be instantiated with an unboxed tuple.
But that's ill-kinded! Function arguments can't be unboxed tuples.
And indeed, you could not expect to do this with a partially-applied
'seq'; it's only going to work when it's fully applied. so it turns
into
case x of _ -> (# p,q #)
For a while I slid by by giving 'seq' an ill-kinded type, but then
the simplifier eta-reduced an application of seq and Lint blew up
with a kind error. It seems more uniform to treat 'seq' as it it
was a language construct.
See Note [seqId magic] in MkId, and
\begin{code}
tcExpr (OpApp arg1 op fix arg2) res_ty
| (L loc (HsVar op_name)) <- op
, op_name `hasKey` seqIdKey
= do { arg1_ty <- newFlexiTyVarTy liftedTypeKind
; let arg2_ty = res_ty
; arg1' <- tcArg op (arg1, arg1_ty, 1)
; arg2' <- tcArg op (arg2, arg2_ty, 2)
; op_id <- tcLookupId op_name
; let op' = L loc (HsWrap (mkWpTyApps [arg1_ty, arg2_ty]) (HsVar op_id))
; return $ OpApp arg1' op' fix arg2' }
| (L loc (HsVar op_name)) <- op
, op_name `hasKey` dollarIdKey
= do { traceTc "Application rule" (ppr op)
; (arg1', arg1_ty) <- tcInferRho arg1
; let doc = ptext (sLit "The first argument of ($) takes")
; (co_arg1, [arg2_ty], op_res_ty) <- matchExpectedFunTys doc 1 arg1_ty
; arg2' <- tcArg op (arg2, arg2_ty, 2)
; co_res <- unifyType op_res_ty res_ty
; op_id <- tcLookupId op_name
; let op' = L loc (HsWrap (mkWpTyApps [arg2_ty, op_res_ty]) (HsVar op_id))
; return $ mkHsWrapCoI co_res $
OpApp (mkLHsWrapCoI co_arg1 arg1') op' fix arg2' }
| otherwise
= do { traceTc "Non Application rule" (ppr op)
; (op', op_ty) <- tcInferFun op
; (co_fn, arg_tys, op_res_ty) <- unifyOpFunTys op 2 op_ty
; co_res <- unifyType op_res_ty res_ty
; [arg1', arg2'] <- tcArgs op [arg1, arg2] arg_tys
; return $ mkHsWrapCoI co_res $
OpApp arg1' (mkLHsWrapCoI co_fn op') fix arg2' }
tcExpr (SectionR op arg2) res_ty
= do { (op', op_ty) <- tcInferFun op
; (co_fn, [arg1_ty, arg2_ty], op_res_ty) <- unifyOpFunTys op 2 op_ty
; co_res <- unifyType (mkFunTy arg1_ty op_res_ty) res_ty
; arg2' <- tcArg op (arg2, arg2_ty, 2)
; return $ mkHsWrapCoI co_res $
SectionR (mkLHsWrapCoI co_fn op') arg2' }
tcExpr (SectionL arg1 op) res_ty
= do { (op', op_ty) <- tcInferFun op
; dflags <- getDOpts
; let n_reqd_args | xopt Opt_PostfixOperators dflags = 1
| otherwise = 2
; (co_fn, (arg1_ty:arg_tys), op_res_ty) <- unifyOpFunTys op n_reqd_args op_ty
; co_res <- unifyType (mkFunTys arg_tys op_res_ty) res_ty
; arg1' <- tcArg op (arg1, arg1_ty, 1)
; return $ mkHsWrapCoI co_res $
SectionL arg1' (mkLHsWrapCoI co_fn op') }
tcExpr (ExplicitTuple tup_args boxity) res_ty
| all tupArgPresent tup_args
= do { let tup_tc = tupleTyCon boxity (length tup_args)
; (coi, arg_tys) <- matchExpectedTyConApp tup_tc res_ty
; tup_args1 <- tcTupArgs tup_args arg_tys
; return $ mkHsWrapCoI coi (ExplicitTuple tup_args1 boxity) }
| otherwise
=
do { let kind = case boxity of { Boxed -> liftedTypeKind
; Unboxed -> argTypeKind }
arity = length tup_args
tup_tc = tupleTyCon boxity arity
; arg_tys <- newFlexiTyVarTys (tyConArity tup_tc) kind
; let actual_res_ty
= mkFunTys [ty | (ty, Missing _) <- arg_tys `zip` tup_args]
(mkTyConApp tup_tc arg_tys)
; coi <- unifyType actual_res_ty res_ty
; tup_args1 <- tcTupArgs tup_args arg_tys
; return $ mkHsWrapCoI coi (ExplicitTuple tup_args1 boxity) }
tcExpr (ExplicitList _ exprs) res_ty
= do { (coi, elt_ty) <- matchExpectedListTy res_ty
; exprs' <- mapM (tc_elt elt_ty) exprs
; return $ mkHsWrapCoI coi (ExplicitList elt_ty exprs') }
where
tc_elt elt_ty expr = tcPolyExpr expr elt_ty
tcExpr (ExplicitPArr _ exprs) res_ty
= do { (coi, elt_ty) <- matchExpectedPArrTy res_ty
; exprs' <- mapM (tc_elt elt_ty) exprs
; return $ mkHsWrapCoI coi (ExplicitPArr elt_ty exprs') }
where
tc_elt elt_ty expr = tcPolyExpr expr elt_ty
\end{code}
%************************************************************************
%* *
Let, case, if, do
%* *
%************************************************************************
\begin{code}
tcExpr (HsLet binds expr) res_ty
= do { (binds', expr') <- tcLocalBinds binds $
tcMonoExpr expr res_ty
; return (HsLet binds' expr') }
tcExpr (HsCase scrut matches) exp_ty
= do {
(scrut', scrut_ty) <- tcInferRho scrut
; traceTc "HsCase" (ppr scrut_ty)
; matches' <- tcMatchesCase match_ctxt scrut_ty matches exp_ty
; return (HsCase scrut' matches') }
where
match_ctxt = MC { mc_what = CaseAlt,
mc_body = tcBody }
tcExpr (HsIf Nothing pred b1 b2) res_ty
= do { pred' <- tcMonoExpr pred boolTy
; b1' <- tcMonoExpr b1 res_ty
; b2' <- tcMonoExpr b2 res_ty
; return (HsIf Nothing pred' b1' b2') }
tcExpr (HsIf (Just fun) pred b1 b2) res_ty
= do { pred_ty <- newFlexiTyVarTy openTypeKind
; b_ty <- newFlexiTyVarTy openTypeKind
; let if_ty = mkFunTys [pred_ty, b_ty, b_ty] res_ty
; fun' <- tcSyntaxOp IfOrigin fun if_ty
; pred' <- tcMonoExpr pred pred_ty
; b1' <- tcMonoExpr b1 b_ty
; b2' <- tcMonoExpr b2 b_ty
; return (HsIf (Just fun') pred' b1' b2') }
tcExpr (HsDo do_or_lc stmts body _) res_ty
= tcDoStmts do_or_lc stmts body res_ty
tcExpr (HsProc pat cmd) res_ty
= do { (pat', cmd', coi) <- tcProc pat cmd res_ty
; return $ mkHsWrapCoI coi (HsProc pat' cmd') }
tcExpr e@(HsArrApp _ _ _ _ _) _
= failWithTc (vcat [ptext (sLit "The arrow command"), nest 2 (ppr e),
ptext (sLit "was found where an expression was expected")])
tcExpr e@(HsArrForm _ _ _) _
= failWithTc (vcat [ptext (sLit "The arrow command"), nest 2 (ppr e),
ptext (sLit "was found where an expression was expected")])
\end{code}
%************************************************************************
%* *
Record construction and update
%* *
%************************************************************************
\begin{code}
tcExpr (RecordCon (L loc con_name) _ rbinds) res_ty
= do { data_con <- tcLookupDataCon con_name
; checkMissingFields data_con rbinds
; (con_expr, con_tau) <- tcInferId con_name
; let arity = dataConSourceArity data_con
(arg_tys, actual_res_ty) = tcSplitFunTysN con_tau arity
con_id = dataConWrapId data_con
; co_res <- unifyType actual_res_ty res_ty
; rbinds' <- tcRecordBinds data_con arg_tys rbinds
; return $ mkHsWrapCoI co_res $
RecordCon (L loc con_id) con_expr rbinds' }
\end{code}
Note [Type of a record update]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
The main complication with RecordUpd is that we need to explicitly
handle the *non-updated* fields. Consider:
data T a b c = MkT1 { fa :: a, fb :: (b,c) }
| MkT2 { fa :: a, fb :: (b,c), fc :: c -> c }
| MkT3 { fd :: a }
upd :: T a b c -> (b',c) -> T a b' c
upd t x = t { fb = x}
The result type should be (T a b' c)
not (T a b c), because 'b' *is not* mentioned in a non-updated field
not (T a b' c'), becuase 'c' *is* mentioned in a non-updated field
NB that it's not good enough to look at just one constructor; we must
look at them all; cf Trac #3219
After all, upd should be equivalent to:
upd t x = case t of
MkT1 p q -> MkT1 p x
MkT2 a b -> MkT2 p b
MkT3 d -> error ...
So we need to give a completely fresh type to the result record,
and then constrain it by the fields that are *not* updated ("p" above).
We call these the "fixed" type variables, and compute them in getFixedTyVars.
Note that because MkT3 doesn't contain all the fields being updated,
its RHS is simply an error, so it doesn't impose any type constraints.
Hence the use of 'relevant_cont'.
Note [Implict type sharing]
~~~~~~~~~~~~~~~~~~~~~~~~~~~
We also take into account any "implicit" non-update fields. For example
data T a b where { MkT { f::a } :: T a a; ... }
So the "real" type of MkT is: forall ab. (a~b) => a -> T a b
Then consider
upd t x = t { f=x }
We infer the type
upd :: T a b -> a -> T a b
upd (t::T a b) (x::a)
= case t of { MkT (co:a~b) (_:a) -> MkT co x }
We can't give it the more general type
upd :: T a b -> c -> T c b
Note [Criteria for update]
~~~~~~~~~~~~~~~~~~~~~~~~~~
We want to allow update for existentials etc, provided the updated
field isn't part of the existential. For example, this should be ok.
data T a where { MkT { f1::a, f2::b->b } :: T a }
f :: T a -> b -> T b
f t b = t { f1=b }
The criterion we use is this:
The types of the updated fields
mention only the universally-quantified type variables
of the data constructor
NB: this is not (quite) the same as being a "naughty" record selector
(See Note [Naughty record selectors]) in TcTyClsDecls), at least
in the case of GADTs. Consider
data T a where { MkT :: { f :: a } :: T [a] }
Then f is not "naughty" because it has a well-typed record selector.
But we don't allow updates for 'f'. (One could consider trying to
allow this, but it makes my head hurt. Badly. And no one has asked
for it.)
In principle one could go further, and allow
g :: T a -> T a
g t = t { f2 = \x -> x }
because the expression is polymorphic...but that seems a bridge too far.
Note [Data family example]
~~~~~~~~~~~~~~~~~~~~~~~~~~
data instance T (a,b) = MkT { x::a, y::b }
--->
data :TP a b = MkT { a::a, y::b }
coTP a b :: T (a,b) ~ :TP a b
Suppose r :: T (t1,t2), e :: t3
Then r { x=e } :: T (t3,t1)
--->
case r |> co1 of
MkT x y -> MkT e y |> co2
where co1 :: T (t1,t2) ~ :TP t1 t2
co2 :: :TP t3 t2 ~ T (t3,t2)
The wrapping with co2 is done by the constructor wrapper for MkT
Outgoing invariants
~~~~~~~~~~~~~~~~~~~
In the outgoing (HsRecordUpd scrut binds cons in_inst_tys out_inst_tys):
* cons are the data constructors to be updated
* in_inst_tys, out_inst_tys have same length, and instantiate the
*representation* tycon of the data cons. In Note [Data
family example], in_inst_tys = [t1,t2], out_inst_tys = [t3,t2]
\begin{code}
tcExpr (RecordUpd record_expr rbinds _ _ _) res_ty
= ASSERT( notNull upd_fld_names )
do {
; sel_ids <- mapM tcLookupField upd_fld_names
; let bad_guys = [ setSrcSpan loc $ addErrTc (notSelector fld_name)
| (fld, sel_id) <- rec_flds rbinds `zip` sel_ids,
not (isRecordSelector sel_id),
let L loc fld_name = hsRecFieldId fld ]
; unless (null bad_guys) (sequence bad_guys >> failM)
; let
sel_id : _ = sel_ids
(tycon, _) = recordSelectorFieldLabel sel_id
data_cons = tyConDataCons tycon
relevant_cons = filter is_relevant data_cons
is_relevant con = all (`elem` dataConFieldLabels con) upd_fld_names
con1 = ASSERT( not (null relevant_cons) ) head relevant_cons
(con1_tvs, _, _, _, _, con1_arg_tys, _) = dataConFullSig con1
con1_flds = dataConFieldLabels con1
con1_res_ty = mkFamilyTyConApp tycon (mkTyVarTys con1_tvs)
; checkTc (not (null relevant_cons)) (badFieldsUpd rbinds)
; let flds1_w_tys = zipEqual "tcExpr:RecConUpd" con1_flds con1_arg_tys
upd_flds1_w_tys = filter is_updated flds1_w_tys
is_updated (fld,_) = fld `elem` upd_fld_names
bad_upd_flds = filter bad_fld upd_flds1_w_tys
con1_tv_set = mkVarSet con1_tvs
bad_fld (fld, ty) = fld `elem` upd_fld_names &&
not (tyVarsOfType ty `subVarSet` con1_tv_set)
; checkTc (null bad_upd_flds) (badFieldTypes bad_upd_flds)
; let fixed_tvs = getFixedTyVars con1_tvs relevant_cons
is_fixed_tv tv = tv `elemVarSet` fixed_tvs
mk_inst_ty tv result_inst_ty
| is_fixed_tv tv = return result_inst_ty
| otherwise = newFlexiTyVarTy (tyVarKind tv)
; (_, result_inst_tys, result_inst_env) <- tcInstTyVars con1_tvs
; scrut_inst_tys <- zipWithM mk_inst_ty con1_tvs result_inst_tys
; let rec_res_ty = substTy result_inst_env con1_res_ty
con1_arg_tys' = map (substTy result_inst_env) con1_arg_tys
scrut_subst = zipTopTvSubst con1_tvs scrut_inst_tys
scrut_ty = substTy scrut_subst con1_res_ty
; co_res <- unifyType rec_res_ty res_ty
; record_expr' <- tcMonoExpr record_expr scrut_ty
; rbinds' <- tcRecordBinds con1 con1_arg_tys' rbinds
; let theta' = substTheta scrut_subst (dataConStupidTheta con1)
; instStupidTheta RecordUpdOrigin theta'
; let scrut_co | Just co_con <- tyConFamilyCoercion_maybe tycon
= WpCast $ mkTyConApp co_con scrut_inst_tys
| otherwise
= idHsWrapper
; return $ mkHsWrapCoI co_res $
RecordUpd (mkLHsWrap scrut_co record_expr') rbinds'
relevant_cons scrut_inst_tys result_inst_tys }
where
upd_fld_names = hsRecFields rbinds
getFixedTyVars :: [TyVar] -> [DataCon] -> TyVarSet
getFixedTyVars tvs1 cons
= mkVarSet [tv1 | con <- cons
, let (tvs, theta, arg_tys, _) = dataConSig con
flds = dataConFieldLabels con
fixed_tvs = exactTyVarsOfTypes fixed_tys
`unionVarSet` tyVarsOfTheta theta
fixed_tys = [ty | (fld,ty) <- zip flds arg_tys
, not (fld `elem` upd_fld_names)]
, (tv1,tv) <- tvs1 `zip` tvs
, tv `elemVarSet` fixed_tvs ]
\end{code}
%************************************************************************
%* *
Arithmetic sequences e.g. [a,b..]
and their parallel-array counterparts e.g. [: a,b.. :]
%* *
%************************************************************************
\begin{code}
tcExpr (ArithSeq _ seq@(From expr)) res_ty
= do { (coi, elt_ty) <- matchExpectedListTy res_ty
; expr' <- tcPolyExpr expr elt_ty
; enum_from <- newMethodFromName (ArithSeqOrigin seq)
enumFromName elt_ty
; return $ mkHsWrapCoI coi (ArithSeq enum_from (From expr')) }
tcExpr (ArithSeq _ seq@(FromThen expr1 expr2)) res_ty
= do { (coi, elt_ty) <- matchExpectedListTy res_ty
; expr1' <- tcPolyExpr expr1 elt_ty
; expr2' <- tcPolyExpr expr2 elt_ty
; enum_from_then <- newMethodFromName (ArithSeqOrigin seq)
enumFromThenName elt_ty
; return $ mkHsWrapCoI coi
(ArithSeq enum_from_then (FromThen expr1' expr2')) }
tcExpr (ArithSeq _ seq@(FromTo expr1 expr2)) res_ty
= do { (coi, elt_ty) <- matchExpectedListTy res_ty
; expr1' <- tcPolyExpr expr1 elt_ty
; expr2' <- tcPolyExpr expr2 elt_ty
; enum_from_to <- newMethodFromName (ArithSeqOrigin seq)
enumFromToName elt_ty
; return $ mkHsWrapCoI coi
(ArithSeq enum_from_to (FromTo expr1' expr2')) }
tcExpr (ArithSeq _ seq@(FromThenTo expr1 expr2 expr3)) res_ty
= do { (coi, elt_ty) <- matchExpectedListTy res_ty
; expr1' <- tcPolyExpr expr1 elt_ty
; expr2' <- tcPolyExpr expr2 elt_ty
; expr3' <- tcPolyExpr expr3 elt_ty
; eft <- newMethodFromName (ArithSeqOrigin seq)
enumFromThenToName elt_ty
; return $ mkHsWrapCoI coi
(ArithSeq eft (FromThenTo expr1' expr2' expr3')) }
tcExpr (PArrSeq _ seq@(FromTo expr1 expr2)) res_ty
= do { (coi, elt_ty) <- matchExpectedPArrTy res_ty
; expr1' <- tcPolyExpr expr1 elt_ty
; expr2' <- tcPolyExpr expr2 elt_ty
; enum_from_to <- newMethodFromName (PArrSeqOrigin seq)
enumFromToPName elt_ty
; return $ mkHsWrapCoI coi
(PArrSeq enum_from_to (FromTo expr1' expr2')) }
tcExpr (PArrSeq _ seq@(FromThenTo expr1 expr2 expr3)) res_ty
= do { (coi, elt_ty) <- matchExpectedPArrTy res_ty
; expr1' <- tcPolyExpr expr1 elt_ty
; expr2' <- tcPolyExpr expr2 elt_ty
; expr3' <- tcPolyExpr expr3 elt_ty
; eft <- newMethodFromName (PArrSeqOrigin seq)
enumFromThenToPName elt_ty
; return $ mkHsWrapCoI coi
(PArrSeq eft (FromThenTo expr1' expr2' expr3')) }
tcExpr (PArrSeq _ _) _
= panic "TcExpr.tcMonoExpr: Infinite parallel array!"
\end{code}
%************************************************************************
%* *
Template Haskell
%* *
%************************************************************************
\begin{code}
#ifdef GHCI /* Only if bootstrapped */
tcExpr (HsSpliceE splice) res_ty = tcSpliceExpr splice res_ty
tcExpr (HsBracket brack) res_ty = do { e <- tcBracket brack res_ty
; return (unLoc e) }
tcExpr e@(HsQuasiQuoteE _) _ =
pprPanic "Should never see HsQuasiQuoteE in type checker" (ppr e)
#endif /* GHCI */
\end{code}
%************************************************************************
%* *
Catch-all
%* *
%************************************************************************
\begin{code}
tcExpr other _ = pprPanic "tcMonoExpr" (ppr other)
\end{code}
%************************************************************************
%* *
Applications
%* *
%************************************************************************
\begin{code}
tcApp :: LHsExpr Name -> [LHsExpr Name]
-> TcRhoType -> TcM (HsExpr TcId)
tcApp (L _ (HsPar e)) args res_ty
= tcApp e args res_ty
tcApp (L _ (HsApp e1 e2)) args res_ty
= tcApp e1 (e2:args) res_ty
tcApp (L loc (HsVar fun)) args res_ty
| fun `hasKey` tagToEnumKey
, [arg] <- args
= tcTagToEnum loc fun arg res_ty
tcApp fun args res_ty
= do {
; (fun1, fun_tau) <- tcInferFun fun
; (co_fun, expected_arg_tys, actual_res_ty)
<- matchExpectedFunTys (mk_app_msg fun) (length args) fun_tau
; co_res <- addErrCtxt (funResCtxt fun) $
unifyType actual_res_ty res_ty
; args1 <- tcArgs fun args expected_arg_tys
; let fun2 = mkLHsWrapCoI co_fun fun1
app = mkLHsWrapCoI co_res (foldl mkHsApp fun2 args1)
; return (unLoc app) }
mk_app_msg :: LHsExpr Name -> SDoc
mk_app_msg fun = sep [ ptext (sLit "The function") <+> quotes (ppr fun)
, ptext (sLit "is applied to")]
tcInferApp :: LHsExpr Name -> [LHsExpr Name]
-> TcM (HsExpr TcId, TcRhoType)
tcInferApp (L _ (HsPar e)) args = tcInferApp e args
tcInferApp (L _ (HsApp e1 e2)) args = tcInferApp e1 (e2:args)
tcInferApp fun args
=
do { (fun1, fun_tau) <- tcInferFun fun
; (co_fun, expected_arg_tys, actual_res_ty)
<- matchExpectedFunTys (mk_app_msg fun) (length args) fun_tau
; args1 <- tcArgs fun args expected_arg_tys
; let fun2 = mkLHsWrapCoI co_fun fun1
app = foldl mkHsApp fun2 args1
; return (unLoc app, actual_res_ty) }
tcInferFun :: LHsExpr Name -> TcM (LHsExpr TcId, TcRhoType)
tcInferFun (L loc (HsVar name))
= do { (fun, ty) <- setSrcSpan loc (tcInferId name)
; return (L loc fun, ty) }
tcInferFun fun
= do { (fun, fun_ty) <- tcInfer (tcMonoExpr fun)
; fun_ty' <- zonkTcTypeCarefully fun_ty
; (wrap, rho) <- deeplyInstantiate AppOrigin fun_ty'
; return (mkLHsWrap wrap fun, rho) }
tcArgs :: LHsExpr Name
-> [LHsExpr Name] -> [TcSigmaType]
-> TcM [LHsExpr TcId]
tcArgs fun args expected_arg_tys
= mapM (tcArg fun) (zip3 args expected_arg_tys [1..])
tcArg :: LHsExpr Name
-> (LHsExpr Name, TcSigmaType, Int)
-> TcM (LHsExpr TcId)
tcArg fun (arg, ty, arg_no) = addErrCtxt (funAppCtxt fun arg arg_no)
(tcPolyExprNC arg ty)
tcTupArgs :: [HsTupArg Name] -> [TcSigmaType] -> TcM [HsTupArg TcId]
tcTupArgs args tys
= ASSERT( equalLength args tys ) mapM go (args `zip` tys)
where
go (Missing {}, arg_ty) = return (Missing arg_ty)
go (Present expr, arg_ty) = do { expr' <- tcPolyExpr expr arg_ty
; return (Present expr') }
unifyOpFunTys :: LHsExpr Name -> Arity -> TcRhoType
-> TcM (CoercionI, [TcSigmaType], TcRhoType)
unifyOpFunTys op arity ty = matchExpectedFunTys herald arity ty
where
herald = ptext (sLit "The operator") <+> quotes (ppr op) <+> ptext (sLit "takes")
tcSyntaxOp :: CtOrigin -> HsExpr Name -> TcType -> TcM (HsExpr TcId)
tcSyntaxOp orig (HsVar op) res_ty = do { (expr, rho) <- tcInferIdWithOrig orig op
; tcWrapResult expr rho res_ty }
tcSyntaxOp _ other _ = pprPanic "tcSyntaxOp" (ppr other)
\end{code}
Note [Push result type in]
~~~~~~~~~~~~~~~~~~~~~~~~~~
Unify with expected result before type-checking the args so that the
info from res_ty percolates to args. This is when we might detect a
too-few args situation. (One can think of cases when the opposite
order would give a better error message.)
experimenting with putting this first.
Here's an example where it actually makes a real difference
class C t a b | t a -> b
instance C Char a Bool
data P t a = forall b. (C t a b) => MkP b
data Q t = MkQ (forall a. P t a)
f1, f2 :: Q Char;
f1 = MkQ (MkP True)
f2 = MkQ (MkP True :: forall a. P Char a)
With the change, f1 will type-check, because the 'Char' info from
the signature is propagated into MkQ's argument. With the check
in the other order, the extra signature in f2 is reqd.
%************************************************************************
%* *
tcInferId
%* *
%************************************************************************
\begin{code}
tcCheckId :: Name -> TcRhoType -> TcM (HsExpr TcId)
tcCheckId name res_ty = do { (expr, rho) <- tcInferId name
; tcWrapResult expr rho res_ty }
tcInferId :: Name -> TcM (HsExpr TcId, TcRhoType)
tcInferId n = tcInferIdWithOrig (OccurrenceOf n) n
tcInferIdWithOrig :: CtOrigin -> Name -> TcM (HsExpr TcId, TcRhoType)
tcInferIdWithOrig orig id_name
= do { id <- lookup_id
; (id_expr, id_rho) <- instantiateOuter orig id
; (wrap, rho) <- deeplyInstantiate orig id_rho
; return (mkHsWrap wrap id_expr, rho) }
where
lookup_id :: TcM TcId
lookup_id
= do { thing <- tcLookup id_name
; case thing of
ATcId { tct_id = id, tct_level = lvl }
-> do { check_naughty id
; checkThLocalId id lvl
; return id }
AGlobal (AnId id)
-> do { check_naughty id; return id }
AGlobal (ADataCon con) -> return (dataConWrapId con)
other -> failWithTc (bad_lookup other) }
bad_lookup thing = ppr thing <+> ptext (sLit "used where a value identifer was expected")
check_naughty id
| isNaughtyRecordSelector id = failWithTc (naughtyRecordSel id)
| otherwise = return ()
instantiateOuter :: CtOrigin -> TcId -> TcM (HsExpr TcId, TcSigmaType)
instantiateOuter orig id
| null tvs && null theta
= return (HsVar id, tau)
| otherwise
= do { (_, tys, subst) <- tcInstTyVars tvs
; doStupidChecks id tys
; let theta' = substTheta subst theta
; traceTc "Instantiating" (ppr id <+> text "with" <+> (ppr tys $$ ppr theta'))
; wrap <- instCall orig tys theta'
; return (mkHsWrap wrap (HsVar id), substTy subst tau) }
where
(tvs, theta, tau) = tcSplitSigmaTy (idType id)
\end{code}
Note [Multiple instantiation]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
We are careful never to make a MethodInst that has, as its meth_id, another MethodInst.
For example, consider
f :: forall a. Eq a => forall b. Ord b => a -> b
At a call to f, at say [Int, Bool], it's tempting to translate the call to
f_m1
where
f_m1 :: forall b. Ord b => Int -> b
f_m1 = f Int dEqInt
f_m2 :: Int -> Bool
f_m2 = f_m1 Bool dOrdBool
But notice that f_m2 has f_m1 as its meth_id. Now the danger is that if we do
a tcSimplCheck with a Given f_mx :: f Int dEqInt, we may make a binding
f_m1 = f_mx
But it's entirely possible that f_m2 will continue to float out, because it
mentions no type variables. Result, f_m1 isn't in scope.
Here's a concrete example that does this (test tc200):
class C a where
f :: Eq b => b -> a -> Int
baz :: Eq a => Int -> a -> Int
instance C Int where
baz = f
Current solution: only do the "method sharing" thing for the first type/dict
application, not for the iterated ones. A horribly subtle point.
Note [No method sharing]
~~~~~~~~~~~~~~~~~~~~~~~~
The -fno-method-sharing flag controls what happens so far as the LIE
is concerned. The default case is that for an overloaded function we
generate a "method" Id, and add the Method Inst to the LIE. So you get
something like
f :: Num a => a -> a
f = /\a (d:Num a) -> let m = (+) a d in \ (x:a) -> m x x
If you specify -fno-method-sharing, the dictionary application
isn't shared, so we get
f :: Num a => a -> a
f = /\a (d:Num a) (x:a) -> (+) a d x x
This gets a bit less sharing, but
a) it's better for RULEs involving overloaded functions
b) perhaps fewer separated lambdas
\begin{code}
doStupidChecks :: TcId
-> [TcType]
-> TcM ()
doStupidChecks fun_id tys
| Just con <- isDataConId_maybe fun_id
= addDataConStupidTheta con tys
| fun_id `hasKey` tagToEnumKey
= failWithTc (ptext (sLit "tagToEnum# must appear applied to one argument"))
| otherwise
= return ()
\end{code}
Note [tagToEnum#]
~~~~~~~~~~~~~~~~~
Nasty check to ensure that tagToEnum# is applied to a type that is an
enumeration TyCon. Unification may refine the type later, but this
check won't see that, alas. It's crude, because it relies on our
knowing *now* that the type is ok, which in turn relies on the
eager-unification part of the type checker pushing enough information
here. In theory the Right Thing to do is to have a new form of
constraint but I definitely cannot face that! And it works ok as-is.
Here's are two cases that should fail
f :: forall a. a
f = tagToEnum# 0 -- Can't do tagToEnum# at a type variable
g :: Int
g = tagToEnum# 0 -- Int is not an enumeration
When data type families are involved it's a bit more complicated.
data family F a
data instance F [Int] = A | B | C
Then we want to generate something like
tagToEnum# R:FListInt 3# |> co :: R:FListInt ~ F [Int]
Usually that coercion is hidden inside the wrappers for
constructors of F [Int] but here we have to do it explicitly.
It's all grotesquely complicated.
\begin{code}
tcTagToEnum :: SrcSpan -> Name -> LHsExpr Name -> TcRhoType -> TcM (HsExpr TcId)
tcTagToEnum loc fun_name arg res_ty
= do { fun <- tcLookupId fun_name
; ty' <- zonkTcType res_ty
; let mb_tc_app = tcSplitTyConApp_maybe ty'
Just (tc, tc_args) = mb_tc_app
; checkTc (isJust mb_tc_app)
(tagToEnumError ty' doc1)
; (coi, rep_tc, rep_args) <- get_rep_ty ty' tc tc_args
; checkTc (isEnumerationTyCon rep_tc)
(tagToEnumError ty' doc2)
; arg' <- tcMonoExpr arg intPrimTy
; let fun' = L loc (HsWrap (WpTyApp rep_ty) (HsVar fun))
rep_ty = mkTyConApp rep_tc rep_args
; return (mkHsWrapCoI coi $ HsApp fun' arg') }
where
doc1 = vcat [ ptext (sLit "Specify the type by giving a type signature")
, ptext (sLit "e.g. (tagToEnum# x) :: Bool") ]
doc2 = ptext (sLit "Result type must be an enumeration type")
doc3 = ptext (sLit "No family instance for this type")
get_rep_ty :: TcType -> TyCon -> [TcType]
-> TcM (CoercionI, TyCon, [TcType])
get_rep_ty ty tc tc_args
| not (isFamilyTyCon tc)
= return (IdCo ty, tc, tc_args)
| otherwise
= do { mb_fam <- tcLookupFamInst tc tc_args
; case mb_fam of
Nothing -> failWithTc (tagToEnumError ty doc3)
Just (rep_tc, rep_args)
-> return ( ACo (mkSymCoercion (mkTyConApp co_tc rep_args))
, rep_tc, rep_args )
where
co_tc = expectJust "tcTagToEnum" $
tyConFamilyCoercion_maybe rep_tc }
tagToEnumError :: TcType -> SDoc -> SDoc
tagToEnumError ty what
= hang (ptext (sLit "Bad call to tagToEnum#")
<+> ptext (sLit "at type") <+> ppr ty)
2 what
\end{code}
%************************************************************************
%* *
Template Haskell checks
%* *
%************************************************************************
\begin{code}
checkThLocalId :: Id -> ThLevel -> TcM ()
#ifndef GHCI /* GHCI and TH is off */
checkThLocalId _id _bind_lvl
= return ()
#else /* GHCI and TH is on */
checkThLocalId id bind_lvl
= do { use_stage <- getStage
; let use_lvl = thLevel use_stage
; checkWellStaged (quotes (ppr id)) bind_lvl use_lvl
; traceTc "thLocalId" (ppr id <+> ppr bind_lvl <+> ppr use_stage <+> ppr use_lvl)
; when (use_lvl > bind_lvl) $
checkCrossStageLifting id bind_lvl use_stage }
checkCrossStageLifting :: Id -> ThLevel -> ThStage -> TcM ()
checkCrossStageLifting _ _ Comp = return ()
checkCrossStageLifting _ _ Splice = return ()
checkCrossStageLifting id _ (Brack _ ps_var lie_var)
| thTopLevelId id
=
keepAliveTc id
| otherwise
=
do { let id_ty = idType id
; checkTc (isTauTy id_ty) (polySpliceErr id)
; lift <- if isStringTy id_ty then
do { sid <- tcLookupId DsMeta.liftStringName
; return (HsVar sid) }
else
setConstraintVar lie_var $ do
newMethodFromName (OccurrenceOf (idName id))
DsMeta.liftName id_ty
; ps <- readMutVar ps_var
; writeMutVar ps_var ((idName id, nlHsApp (noLoc lift) (nlHsVar id)) : ps)
; return () }
#endif /* GHCI */
\end{code}
Note [Lifting strings]
~~~~~~~~~~~~~~~~~~~~~~
If we see $(... [| s |] ...) where s::String, we don't want to
generate a mass of Cons (CharL 'x') (Cons (CharL 'y') ...)) etc.
So this conditional short-circuits the lifting mechanism to generate
(liftString "xy") in that case. I didn't want to use overlapping instances
for the Lift class in TH.Syntax, because that can lead to overlapping-instance
errors in a polymorphic situation.
If this check fails (which isn't impossible) we get another chance; see
Note [Converting strings] in Convert.lhs
Local record selectors
~~~~~~~~~~~~~~~~~~~~~~
Record selectors for TyCons in this module are ordinary local bindings,
which show up as ATcIds rather than AGlobals. So we need to check for
naughtiness in both branches. c.f. TcTyClsBindings.mkAuxBinds.
%************************************************************************
%* *
\subsection{Record bindings}
%* *
%************************************************************************
Game plan for record bindings
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1. Find the TyCon for the bindings, from the first field label.
2. Instantiate its tyvars and unify (T a1 .. an) with expected_ty.
For each binding field = value
3. Instantiate the field type (from the field label) using the type
envt from step 2.
4 Type check the value using tcArg, passing the field type as
the expected argument type.
This extends OK when the field types are universally quantified.
\begin{code}
tcRecordBinds
:: DataCon
-> [TcType]
-> HsRecordBinds Name
-> TcM (HsRecordBinds TcId)
tcRecordBinds data_con arg_tys (HsRecFields rbinds dd)
= do { mb_binds <- mapM do_bind rbinds
; return (HsRecFields (catMaybes mb_binds) dd) }
where
flds_w_tys = zipEqual "tcRecordBinds" (dataConFieldLabels data_con) arg_tys
do_bind fld@(HsRecField { hsRecFieldId = L loc field_lbl, hsRecFieldArg = rhs })
| Just field_ty <- assocMaybe flds_w_tys field_lbl
= addErrCtxt (fieldCtxt field_lbl) $
do { rhs' <- tcPolyExprNC rhs field_ty
; let field_id = mkUserLocal (nameOccName field_lbl)
(nameUnique field_lbl)
field_ty loc
; return (Just (fld { hsRecFieldId = L loc field_id, hsRecFieldArg = rhs' })) }
| otherwise
= do { addErrTc (badFieldCon data_con field_lbl)
; return Nothing }
checkMissingFields :: DataCon -> HsRecordBinds Name -> TcM ()
checkMissingFields data_con rbinds
| null field_labels
= if any isBanged field_strs then
addErrTc (missingStrictFields data_con [])
else
return ()
| otherwise = do
unless (null missing_s_fields)
(addErrTc (missingStrictFields data_con missing_s_fields))
warn <- doptM Opt_WarnMissingFields
unless (not (warn && notNull missing_ns_fields))
(warnTc True (missingFields data_con missing_ns_fields))
where
missing_s_fields
= [ fl | (fl, str) <- field_info,
isBanged str,
not (fl `elem` field_names_used)
]
missing_ns_fields
= [ fl | (fl, str) <- field_info,
not (isBanged str),
not (fl `elem` field_names_used)
]
field_names_used = hsRecFields rbinds
field_labels = dataConFieldLabels data_con
field_info = zipEqual "missingFields"
field_labels
field_strs
field_strs = dataConStrictMarks data_con
\end{code}
%************************************************************************
%* *
\subsection{Errors and contexts}
%* *
%************************************************************************
Boring and alphabetical:
\begin{code}
addExprErrCtxt :: LHsExpr Name -> TcM a -> TcM a
addExprErrCtxt expr = addErrCtxt (exprCtxt expr)
exprCtxt :: LHsExpr Name -> SDoc
exprCtxt expr
= hang (ptext (sLit "In the expression:")) 2 (ppr expr)
fieldCtxt :: Name -> SDoc
fieldCtxt field_name
= ptext (sLit "In the") <+> quotes (ppr field_name) <+> ptext (sLit "field of a record")
funAppCtxt :: LHsExpr Name -> LHsExpr Name -> Int -> SDoc
funAppCtxt fun arg arg_no
= hang (hsep [ ptext (sLit "In the"), speakNth arg_no, ptext (sLit "argument of"),
quotes (ppr fun) <> text ", namely"])
2 (quotes (ppr arg))
funResCtxt :: LHsExpr Name -> SDoc
funResCtxt fun
= ptext (sLit "In the return type of a call of") <+> quotes (ppr fun)
badFieldTypes :: [(Name,TcType)] -> SDoc
badFieldTypes prs
= hang (ptext (sLit "Record update for insufficiently polymorphic field")
<> plural prs <> colon)
2 (vcat [ ppr f <+> dcolon <+> ppr ty | (f,ty) <- prs ])
badFieldsUpd :: HsRecFields Name a -> SDoc
badFieldsUpd rbinds
= hang (ptext (sLit "No constructor has all these fields:"))
2 (pprQuotedList (hsRecFields rbinds))
naughtyRecordSel :: TcId -> SDoc
naughtyRecordSel sel_id
= ptext (sLit "Cannot use record selector") <+> quotes (ppr sel_id) <+>
ptext (sLit "as a function due to escaped type variables") $$
ptext (sLit "Probable fix: use pattern-matching syntax instead")
notSelector :: Name -> SDoc
notSelector field
= hsep [quotes (ppr field), ptext (sLit "is not a record selector")]
missingStrictFields :: DataCon -> [FieldLabel] -> SDoc
missingStrictFields con fields
= header <> rest
where
rest | null fields = empty
| otherwise = colon <+> pprWithCommas ppr fields
header = ptext (sLit "Constructor") <+> quotes (ppr con) <+>
ptext (sLit "does not have the required strict field(s)")
missingFields :: DataCon -> [FieldLabel] -> SDoc
missingFields con fields
= ptext (sLit "Fields of") <+> quotes (ppr con) <+> ptext (sLit "not initialised:")
<+> pprWithCommas ppr fields
#ifdef GHCI
polySpliceErr :: Id -> SDoc
polySpliceErr id
= ptext (sLit "Can't splice the polymorphic local variable") <+> quotes (ppr id)
#endif
\end{code}