10.2. Warnings and sanity-checking — Glasgow Haskell Compiler 8.6.5 User's Guide

# Glasgow Haskell Compiler User's Guide

# 10.2. Warnings and sanity-checking

GHC has a number of options that select which types of non-fatal error messages, otherwise known as warnings, can be generated during compilation. By default, you get a standard set of warnings which are generally likely to indicate bugs in your program. These are:

`-Woverlapping-patterns` `-Wwarnings-deprecations` `-Wdeprecations` `-Wdeprecated-flags` `-Wunrecognised-pragmas` `-Wduplicate-constraints` `-Wduplicate-exports` | `-Woverflowed-literals` `-Wempty-enumerations` `-Wmissing-fields` `-Wmissing-methods` `-Wwrong-do-bind` `-Wunsupported-calling-conventions` `-Wdodgy-foreign-imports` | `-Winline-rule-shadowing` `-Wunsupported-llvm-version` `-Wtabs` `-Wunrecognised-warning-flags` `-Winaccessible-code` `-Wstar-is-type` `-Wstar-binder`

The following flags are simple ways to select standard “packages” of warnings:

`-W`

  Provides the standard warnings plus

  `-Wunused-binds` `-Wunused-matches` `-Wunused-foralls` | `-Wunused-imports` `-Wincomplete-patterns` `-Wdodgy-exports` | `-Wdodgy-imports` `-Wunbanged-strict-patterns`

`-Wall`

  Turns on all warning options that indicate potentially suspicious code. The warnings that are not enabled by `-Wall` are

  `-Wincomplete-uni-patterns` `-Wincomplete-record-updates` `-Wmonomorphism-restriction` `-Wimplicit-prelude` `-Wmissing-local-signatures` | `-Wmissing-exported-signatures` `-Wmissing-export-lists` `-Wmissing-import-lists` `-Wmissing-home-modules` `-Widentities` | `-Wredundant-constraints` `-Wpartial-fields` `-Wmissed-specialisations` `-Wall-missed-specialisations`

`-Weverything`

  Turns on every single warning supported by the compiler.

`-Wcompat`

  Turns on warnings that will be enabled by default in the future, but remain off in normal compilations for the time being. This allows library authors eager to make their code future compatible to adapt to new features before they even generate warnings.

  This currently enables

  `-Wmissing-monadfail-instances` `-Wsemigroup` | `-Wnoncanonical-monoid-instances` | `-Wimplicit-kind-vars`

`-Wno-compat`

  Disables all warnings enabled by `-Wcompat`.

`-w`

  Turns off all warnings, including the standard ones and those that `-Wall` doesn’t enable.

These options control which warnings are considered fatal and cause compilation to abort.

`-Werror`

  Makes any warning into a fatal error. Useful so that you don’t miss warnings when doing batch compilation.

`-Werror``=⟨wflag⟩`

  Implies: | `-W<wflag>`

  Makes a specific warning into a fatal error. The warning will be enabled if it hasn’t been enabled yet.

  `-Werror=compat` has the same effect as `-Werror=...` for each warning flag in the `-Wcompat` option group.

`-Wwarn`

  Warnings are treated only as warnings, not as errors. This is the default, but can be useful to negate a `-Werror` flag.

`-Wwarn``=⟨wflag⟩`

  Causes a specific warning to be treated as normal warning, not fatal error.

  Note that it doesn’t fully negate the effects of `-Werror=<wflag>` - the warning will still be enabled.

  `-Wwarn=compat` has the same effect as `-Wwarn=...` for each warning flag in the `-Wcompat` option group.

When a warning is emitted, the specific warning flag which controls it is shown.

`-fshow-warning-groups`

  When showing which flag controls a warning, also show the respective warning group flag(s) that warning is contained in.

  This option is off by default.

The full set of warning options is described below. To turn off any warning, simply give the corresponding `-Wno-...` option on the command line. For backwards compatibility with GHC versions prior to 8.0, all these warnings can still be controlled with `-f(no-)warn-*` instead of `-W(no-)*`.

`-Wunrecognised-warning-flags`

  Enables warnings when the compiler encounters a `-W...` flag that is not recognised.

  This warning is on by default.

`-Wtyped-holes`

  Determines whether the compiler reports typed holes warnings. Has no effect unless typed holes errors are deferred until runtime. See Typed Holes and Deferring type errors to runtime

  This warning is on by default.

`-Wdeferred-type-errors`

  Causes a warning to be reported when a type error is deferred until runtime. See Deferring type errors to runtime

  This warning is on by default.

`-fdefer-type-errors`

  Implies: | `-fdefer-typed-holes`, `-fdefer-out-of-scope-variables`

  Defer as many type errors as possible until runtime. At compile time you get a warning (instead of an error). At runtime, if you use a value that depends on a type error, you get a runtime error; but you can run any type-correct parts of your code just fine. See Deferring type errors to runtime

`-fdefer-typed-holes`

  Defer typed holes errors (errors about names with a leading underscore (e.g., “_”, “_foo”, “_bar”)) until runtime. This will turn the errors produced by typed holes into warnings. Using a value that depends on a typed hole produces a runtime error, the same as `-fdefer-type-errors` (which implies this option). See Typed Holes and Deferring type errors to runtime.

  Implied by `-fdefer-type-errors`. See also `-Wtyped-holes`.

`-fdefer-out-of-scope-variables`

  Defer variable out-of-scope errors (errors about names without a leading underscore) until runtime. This will turn variable-out-of-scope errors into warnings. Using a value that depends on a typed hole produces a runtime error, the same as `-fdefer-type-errors` (which implies this option). See Typed Holes and Deferring type errors to runtime.

  Implied by `-fdefer-type-errors`. See also `-Wdeferred-out-of-scope-variables`.

`-Wdeferred-out-of-scope-variables`

  Warn when a deferred out-of-scope variable is encountered.

`-Wpartial-type-signatures`

  Determines whether the compiler reports holes in partial type signatures as warnings. Has no effect unless `-XPartialTypeSignatures` is enabled, which controls whether errors should be generated for holes in types or not. See Partial Type Signatures.

  This warning is on by default.

`-fhelpful-errors`

  When a name or package is not found in scope, make suggestions for the name or package you might have meant instead.

  This option is on by default.

`-Wunrecognised-pragmas`

  Causes a warning to be emitted when a pragma that GHC doesn’t recognise is used. As well as pragmas that GHC itself uses, GHC also recognises pragmas known to be used by other tools, e.g. `OPTIONS_HUGS` and `DERIVE`.

  This option is on by default.

`-Wmissed-specialisations`

  Emits a warning if GHC cannot specialise an overloaded function, usually because the function needs an `INLINABLE` pragma. Reports when the situation arises during specialisation of an imported function.

  This form is intended to catch cases where an imported function that is marked as `INLINABLE` (presumably to enable specialisation) cannot be specialised as it calls other functions that are themselves not specialised.

  Note that this warning will not throw errors if used with `-Werror`.

  This option is off by default.

`-Wall-missed-specialisations`

  Emits a warning if GHC cannot specialise an overloaded function, usually because the function needs an `INLINABLE` pragma. Reports all such situations.

  Note that this warning will not throw errors if used with `-Werror`.

  This option is off by default.

`-Wwarnings-deprecations`

  Causes a warning to be emitted when a module, function or type with a `WARNING` or `DEPRECATED pragma` is used. See WARNING and DEPRECATED pragmas for more details on the pragmas.

  This option is on by default.

`-Wdeprecations`

  Causes a warning to be emitted when a module, function or type with a `WARNING` or `DEPRECATED pragma` is used. See WARNING and DEPRECATED pragmas for more details on the pragmas. An alias for `-Wwarnings-deprecations`.

  This option is on by default.

`-Wamp`

  This option is deprecated.

  Caused a warning to be emitted when a definition was in conflict with the AMP (Applicative-Monad proosal).

`-Wnoncanonical-monad-instances`

  Warn if noncanonical `Applicative` or `Monad` instances declarations are detected.

  When this warning is enabled, the following conditions are verified:

  In `Monad` instances declarations warn if any of the following conditions does not hold:

  > - If `return` is defined it must be canonical (i.e. `return = pure`).
  > - If `(>>)` is defined it must be canonical (i.e. `(>>) = (*>)`).

  Moreover, in `Applicative` instance declarations:

  > - Warn if `pure` is defined backwards (i.e. `pure = return`).
  > - Warn if `(*>)` is defined backwards (i.e. `(*>) = (>>)`).

  This option is off by default.

`-Wnoncanonical-monadfail-instances`

  Warn if noncanonical `Monad` or `MonadFail` instances declarations are detected.

  When this warning is enabled, the following conditions are verified:

  In `Monad` instances declarations warn if any of the following conditions does not hold:

  > - If `fail` is defined it must be canonical (i.e. `fail = Control.Monad.Fail.fail`).

  Moreover, in `MonadFail` instance declarations:

  > - Warn if `fail` is defined backwards (i.e. `fail = Control.Monad.fail`).

  See also `-Wmissing-monadfail-instances`.

  This option is off by default.

`-Wnoncanonical-monoid-instances`

  Warn if noncanonical `Semigroup` or `Monoid` instances declarations are detected.

  When this warning is enabled, the following conditions are verified:

  In `Monoid` instances declarations warn if any of the following conditions does not hold:

  > - If `mappend` is defined it must be canonical (i.e. `mappend = (Data.Semigroup.<>)`).

  Moreover, in `Semigroup` instance declarations:

  > - Warn if `(<>)` is defined backwards (i.e. `(<>) = mappend`).

  This warning is off by default. However, it is part of the `-Wcompat` option group.

`-Wmissing-monadfail-instances`

  Warn when a failable pattern is used in a do-block that does not have a `MonadFail` instance.

  See also `-Wnoncanonical-monadfail-instances`.

  Being part of the `-Wcompat` option group, this warning is off by default, but will be switched on in a future GHC release, as part of the MonadFail Proposal (MFP).

`-Wsemigroup`

  Warn when definitions are in conflict with the future inclusion of `Semigroup` into the standard typeclasses.

  > 1. Instances of `Monoid` should also be instances of `Semigroup`
  > 2. The `Semigroup` operator `(<>)` will be in `Prelude`, which clashes with custom local definitions of such an operator

  Being part of the `-Wcompat` option group, this warning is off by default, but will be switched on in a future GHC release.

`-Wdeprecated-flags`

  Causes a warning to be emitted when a deprecated command-line flag is used.

  This option is on by default.

`-Wunsupported-calling-conventions`

  Causes a warning to be emitted for foreign declarations that use unsupported calling conventions. In particular, if the `stdcall` calling convention is used on an architecture other than i386 then it will be treated as `ccall`.

`-Wdodgy-foreign-imports`

  Causes a warning to be emitted for foreign imports of the following form:

      foreign import "f" f :: FunPtr t

  on the grounds that it probably should be

      foreign import "&f" f :: FunPtr t

  The first form declares that `f` is a (pure) C function that takes no arguments and returns a pointer to a C function with type `t`, whereas the second form declares that `f` itself is a C function with type `t`. The first declaration is usually a mistake, and one that is hard to debug because it results in a crash, hence this warning.

`-Wdodgy-exports`

  Causes a warning to be emitted when a datatype `T` is exported with all constructors, i.e. `T(..)`, but is it just a type synonym.

  Also causes a warning to be emitted when a module is re-exported, but that module exports nothing.

`-Wdodgy-imports`

  Causes a warning to be emitted in the following cases:

  - When a datatype `T` is imported with all constructors, i.e. `T(..)`, but has been exported abstractly, i.e. `T`.
  - When an `import` statement hides an entity that is not exported.

`-Woverflowed-literals`

  Causes a warning to be emitted if a literal will overflow, e.g. `300 :: Word8`.

`-Wempty-enumerations`

  Causes a warning to be emitted if an enumeration is empty, e.g. `[5 .. 3]`.

`-Wduplicate-constraints`

  Have the compiler warn about duplicate constraints in a type signature. For example

      f :: (Eq a, Show a, Eq a) => a -> a

  The warning will indicate the duplicated `Eq a` constraint.

  This option is now deprecated in favour of `-Wredundant-constraints`.

`-Wredundant-constraints`

  Since: | 8.0

  Have the compiler warn about redundant constraints in a type signature. In particular:

  - A redundant constraint within the type signature itself:

        f :: (Eq a, Ord a) => a -> a

    The warning will indicate the redundant `Eq a` constraint: it is subsumed by the `Ord a` constraint.

  - A constraint in the type signature is not used in the code it covers:

        f :: Eq a => a -> a -> Bool
        f x y = True

    The warning will indicate the redundant `Eq a` constraint: : it is not used by the definition of `f`.)

  Similar warnings are given for a redundant constraint in an instance declaration.

  When turning on, you can suppress it on a per-module basis with `-Wno-redundant-constraints`. Occasionally you may specifically want a function to have a more constrained signature than necessary, perhaps to leave yourself wiggle-room for changing the implementation without changing the API. In that case, you can suppress the warning on a per-function basis, using a call in a dead binding. For example:

      f :: Eq a => a -> a -> Bool
      f x y = True
      where
          _ = x == x  -- Suppress the redundant-constraint warning for (Eq a)

  Here the call to `(==)` makes GHC think that the `(Eq a)` constraint is needed, so no warning is issued.

`-Wduplicate-exports`

  Have the compiler warn about duplicate entries in export lists. This is useful information if you maintain large export lists, and want to avoid the continued export of a definition after you’ve deleted (one) mention of it in the export list.

  This option is on by default.

`-Whi-shadowing`

  Causes the compiler to emit a warning when a module or interface file in the current directory is shadowing one with the same module name in a library or other directory.

`-Widentities`

  Causes the compiler to emit a warning when a Prelude numeric conversion converts a type `T` to the same type `T`; such calls are probably no-ops and can be omitted. The functions checked for are: `toInteger`, `toRational`, `fromIntegral`, and `realToFrac`.

`-Wimplicit-prelude`

  Have the compiler warn if the Prelude is implicitly imported. This happens unless either the Prelude module is explicitly imported with an `import ... Prelude ...` line, or this implicit import is disabled (either by `-XNoImplicitPrelude` or a `LANGUAGE NoImplicitPrelude` pragma).

  Note that no warning is given for syntax that implicitly refers to the Prelude, even if `-XNoImplicitPrelude` would change whether it refers to the Prelude. For example, no warning is given when `368` means `Prelude.fromInteger (368::Prelude.Integer)` (where `Prelude` refers to the actual Prelude module, regardless of the imports of the module being compiled).

  This warning is off by default.

`-Wimplicit-kind-vars`

  Since: | 8.6

  GHC proposal #24 prescribes to treat kind variables and type variables identically in `forall`, removing the legacy distinction between them.

  Consider the following examples:

      f :: Proxy a -> Proxy b -> ()
      g :: forall a b. Proxy a -> Proxy b -> ()

  `f` does not use an explicit `forall`, so type variables `a` and `b` are brought into scope implicitly. `g` quantifies both `a` and `b` explicitly. Both `f` and `g` work today and will continue to work in the future because they adhere to the “forall-or-nothing” rule: either all type variables in a function definition are introduced explicitly or implicitly, there is no middle ground.

  A violation of the “forall-or-nothing” rule looks like this:

      m :: forall a. Proxy a -> Proxy b -> ()

  `m` does not introduce one of the variables, `b`, and thus is rejected.

  However, consider the following example:

      n :: forall a. Proxy (a :: k) -> ()

  While `n` uses `k` without introducing it and thus violates the rule, it is currently accepted. This is because `k` in `n` is considered a kind variable, as it occurs in a kind signature. In reality, the line between type variables and kind variables is blurry, as the following example demonstrates:

      kindOf :: forall a. Proxy (a :: k) -> Proxy k

  In `kindOf`, the `k` variable is used both in a kind position and a type position. Currently, `kindOf` happens to be accepted as well.

  In a future release of GHC, both `n` and `kindOf` will be rejected per the “forall-or-nothing” rule. This warning, being part of the `-Wcompat` option group, allows to detect this before the actual breaking change takes place.

`-Wincomplete-patterns`

  The option `-Wincomplete-patterns` warns about places where a pattern-match might fail at runtime. The function `g` below will fail when applied to non-empty lists, so the compiler will emit a warning about this when `-Wincomplete-patterns` is enabled.

      g [] = 2

  This option isn’t enabled by default because it can be a bit noisy, and it doesn’t always indicate a bug in the program. However, it’s generally considered good practice to cover all the cases in your functions, and it is switched on by `-W`.

`-Wincomplete-uni-patterns`

  The flag `-Wincomplete-uni-patterns` is similar to `-Wincomplete-patterns`, except that it applies only to lambda-expressions and pattern bindings, constructs that only allow a single pattern:

      h = \[] -> 2
      Just k = f y

`-fmax-pmcheck-iterations``=⟨n⟩`

  Default: | 2000000

  Sets how many iterations of the pattern-match checker will perform before giving up. This limit is to catch cases where pattern-match checking might be excessively costly (due to the exponential complexity of coverage checking in the general case). It typically shouldn’t be necessary to set this unless GHC informs you that it has exceeded the pattern match checker’s iteration limit (in which case you may want to consider refactoring your pattern match, for the sake of future readers of your code.

`-Wincomplete-record-updates`

  The function `f` below will fail when applied to `Bar`, so the compiler will emit a warning about this when `-Wincomplete-record-updates` is enabled.

      data Foo = Foo { x :: Int }
               | Bar

      f :: Foo -> Foo
      f foo = foo { x = 6 }

  This option isn’t enabled by default because it can be very noisy, and it often doesn’t indicate a bug in the program.

`-Wmissing-fields`

  This option is on by default, and warns you whenever the construction of a labelled field constructor isn’t complete, missing initialisers for one or more fields. While not an error (the missing fields are initialised with bottoms), it is often an indication of a programmer error.

`-Wmissing-export-lists`

  Since: | 8.4.1

  This flag warns if you declare a module without declaring an explicit export list. For example

      module M where

        p x = x

  The `-Wmissing-export-lists` flag will warn that `M` does not declare an export list. Declaring an explicit export list for `M` enables GHC dead code analysis, prevents accidental export of names and can ease optimizations like inlining.

`-Wmissing-import-lists`

  This flag warns if you use an unqualified `import` declaration that does not explicitly list the entities brought into scope. For example

      module M where
        import X( f )
        import Y
        import qualified Z
        p x = f x x

  The `-Wmissing-import-lists` flag will warn about the import of `Y` but not `X` If module `Y` is later changed to export (say) `f`, then the reference to `f` in `M` will become ambiguous. No warning is produced for the import of `Z` because extending `Z`‘s exports would be unlikely to produce ambiguity in `M`.

`-Wmissing-methods`

  This option is on by default, and warns you whenever an instance declaration is missing one or more methods, and the corresponding class declaration has no default declaration for them.

  The `MINIMAL` pragma can be used to change which combination of methods will be required for instances of a particular class. See MINIMAL pragma.

`-Wmissing-signatures`

  If you would like GHC to check that every top-level function/value has a type signature, use the `-Wmissing-signatures` option. As part of the warning GHC also reports the inferred type. The option is off by default.

`-Wmissing-exported-sigs`

  This option is now deprecated in favour of `-Wmissing-exported-signatures`.

`-Wmissing-exported-signatures`

  If you would like GHC to check that every exported top-level function/value has a type signature, but not check unexported values, use the `-Wmissing-exported-signatures` option. This option takes precedence over `-Wmissing-signatures`. As part of the warning GHC also reports the inferred type. The option is off by default.

`-Wmissing-local-sigs`

  This option is now deprecated in favour of `-Wmissing-local-signatures`.

`-Wmissing-local-signatures`

  If you use the `-Wmissing-local-signatures` flag GHC will warn you about any polymorphic local bindings. As part of the warning GHC also reports the inferred type. The option is off by default.

`-Wmissing-pattern-synonym-signatures`

  If you would like GHC to check that every pattern synonym has a type signature, use the `-Wmissing-pattern-synonym-signatures` option. If this option is used in conjunction with `-Wmissing-exported-signatures` then only exported pattern synonyms must have a type signature. GHC also reports the inferred type. This option is off by default.

`-Wname-shadowing`

  This option causes a warning to be emitted whenever an inner-scope value has the same name as an outer-scope value, i.e. the inner value shadows the outer one. This can catch typographical errors that turn into hard-to-find bugs, e.g., in the inadvertent capture of what would be a recursive call in `f = ... let f = id in ... f ...`.

  The warning is suppressed for names beginning with an underscore. For example

      f x = do { _ignore <- this; _ignore <- that; return (the other) }

`-Worphans`

  These flags cause a warning to be emitted whenever the module contains an “orphan” instance declaration or rewrite rule. An instance declaration is an orphan if it appears in a module in which neither the class nor the type being instanced are declared in the same module. A rule is an orphan if it is a rule for a function declared in another module. A module containing any orphans is called an orphan module.

  The trouble with orphans is that GHC must pro-actively read the interface files for all orphan modules, just in case their instances or rules play a role, whether or not the module’s interface would otherwise be of any use. See Orphan modules and instance declarations for details.

  The flag `-Worphans` warns about user-written orphan rules or instances.

`-Woverlapping-patterns`

  By default, the compiler will warn you if a set of patterns are overlapping, e.g.,

      f :: String -> Int
      f []     = 0
      f (_:xs) = 1
      f "2"    = 2

  where the last pattern match in `f` won’t ever be reached, as the second pattern overlaps it. More often than not, redundant patterns is a programmer mistake/error, so this option is enabled by default.

`-Winaccessible-code`

  By default, the compiler will warn you if types make a branch inaccessible. This generally requires GADTs or similar extensions.

  Take, for example, the following program

      {-# LANGUAGE GADTs #-}

      data Foo a where
       Foo1 :: Foo Char
       Foo2 :: Foo Int

      data TyEquality a b where
              Refl :: TyEquality a a

      checkTEQ :: Foo t -> Foo u -> Maybe (TyEquality t u)
      checkTEQ x y = error "unimportant"

      step2 :: Bool
      step2 = case checkTEQ Foo1 Foo2 of
               Just Refl -> True -- Inaccessible code
               Nothing -> False

  The `Just Refl` case in `step2` is inaccessible, because in order for `checkTEQ` to be able to produce a `Just`, `t ~ u` must hold, but since we’re passing `Foo1` and `Foo2` here, it follows that `t ~ Char`, and `u ~ Int`, and thus `t ~ u` cannot hold.

`-Wstar-is-type`

  Since: | 8.6

  The use of `*` to denote the kind of inhabited types relies on the `StarIsType` extension, which in a future release will be turned off by default and then possibly removed. The reasons for this and the deprecation schedule are described in GHC proposal #30.

  This warning allows to detect such uses of `*` before the actual breaking change takes place. The recommended fix is to replace `*` with `Type` imported from `Data.Kind`.

`-Wstar-binder`

  Under `-XStarIsType`, a `*` in types is not an operator nor even a name, it is special syntax that stands for `Data.Kind.Type`. This means that an expression like `Either * Char` is parsed as `Either (*) Char` and not `(*) Either Char`.

  In binding positions, we have similar parsing rules. Consider the following example

      {-# LANGUAGE TypeOperators, TypeFamilies, StarIsType #-}

      type family a + b
      type family a * b

  While `a + b` is parsed as `(+) a b` and becomes a binding position for the `(+)` type operator, `a * b` is parsed as `a (*) b` and is rejected.

  As a workaround, we allow to bind `(*)` in prefix form:

      type family (*) a b

  This is a rather fragile arrangement, as generally a programmer expects `(*) a b` to be equivalent to `a * b`. With `-Wstar-binder` we warn when this special treatment of `(*)` takes place.

`-Wsimplifiable-class-constraints`

  Since: | 8.2

  Warn about class constraints in a type signature that can be simplified using a top-level instance declaration. For example:

      f :: Eq [a] => a -> a

  Here the `Eq [a]` in the signature overlaps with the top-level instance for `Eq [a]`. GHC goes to some efforts to use the former, but if it should use the latter, it would then have an insoluble `Eq a` constraint. Best avoided by instead writing:

      f :: Eq a => a -> a

  This option is on by default. As usual you can suppress it on a per-module basis with `-Wno-simplifiable-class-constraints`.

`-Wtabs`

  Have the compiler warn if there are tabs in your source file.

`-Wtype-defaults`

  Have the compiler warn/inform you where in your source the Haskell defaulting mechanism for numeric types kicks in. This is useful information when converting code from a context that assumed one default into one with another, e.g., the ‘default default’ for Haskell 1.4 caused the otherwise unconstrained value `1` to be given the type `Int`, whereas Haskell 98 and later defaults it to `Integer`. This may lead to differences in performance and behaviour, hence the usefulness of being non-silent about this.

  This warning is off by default.

`-Wmonomorphism-restriction`

  Have the compiler warn/inform you where in your source the Haskell Monomorphism Restriction is applied. If applied silently the MR can give rise to unexpected behaviour, so it can be helpful to have an explicit warning that it is being applied.

  This warning is off by default.

`-Wunsupported-llvm-version`

  Warn when using `-fllvm` with an unsupported version of LLVM.

`-Wunticked-promoted-constructors`

  Warn if a promoted data constructor is used without a tick preceding its name.

  For example:

      data Nat = Succ Nat | Zero

      data Vec n s where
        Nil  :: Vec Zero a
        Cons :: a -> Vec n a -> Vec (Succ n) a

  Will raise two warnings because `Zero` and `Succ` are not written as `'Zero` and `'Succ`.

  This warning is enabled by default in `-Wall` mode.

`-Wunused-binds`

  Report any function definitions (and local bindings) which are unused. An alias for

  - `-Wunused-top-binds`
  - `-Wunused-local-binds`
  - `-Wunused-pattern-binds`

`-Wunused-top-binds`

  Report any function definitions which are unused.

  More precisely, warn if a binding brings into scope a variable that is not used, except if the variable’s name starts with an underscore. The “starts-with-underscore” condition provides a way to selectively disable the warning.

  A variable is regarded as “used” if

  - It is exported, or
  - It appears in the right hand side of a binding that binds at least one used variable that is used

  For example:

      module A (f) where
      f = let (p,q) = rhs1 in t p  -- No warning: q is unused, but is locally bound
      t = rhs3                     -- No warning: f is used, and hence so is t
      g = h x                      -- Warning: g unused
      h = rhs2                     -- Warning: h is only used in the
                                   -- right-hand side of another unused binding
      _w = True                    -- No warning: _w starts with an underscore

`-Wunused-local-binds`

  Report any local definitions which are unused. For example:

      module A (f) where
      f = let (p,q) = rhs1 in t p  -- Warning: q is unused
      g = h x                      -- No warning: g is unused, but is a top-level binding

`-Wunused-pattern-binds`

  Warn if a pattern binding binds no variables at all, unless it is a lone wild-card pattern, or a banged pattern. For example:

      Just _ = rhs3    -- Warning: unused pattern binding
      (_, _) = rhs4    -- Warning: unused pattern binding
      _  = rhs3        -- No warning: lone wild-card pattern
      !() = rhs4       -- No warning: banged pattern; behaves like seq

  In general a lazy pattern binding p = e is a no-op if p does not bind any variables. The motivation for allowing lone wild-card patterns is they are not very different from `_v = rhs3`, which elicits no warning; and they can be useful to add a type constraint, e.g. `_ = x::Int`. A banged pattern (see Bang patterns and Strict Haskell) is not a no-op, because it forces evaluation, and is useful as an alternative to `seq`.

`-Wunused-imports`

  Report any modules that are explicitly imported but never used. However, the form `import M()` is never reported as an unused import, because it is a useful idiom for importing instance declarations, which are anonymous in Haskell.

`-Wunused-matches`

  Report all unused variables which arise from term-level pattern matches, including patterns consisting of a single variable. For instance `f x y = []` would report `x` and `y` as unused. The warning is suppressed if the variable name begins with an underscore, thus:

      f _x = True

  Note that `-Wunused-matches` does not warn about variables which arise from type-level patterns, as found in type family and data family instances. This must be enabled separately through the `-Wunused-type-patterns` flag.

`-Wunused-do-bind`

  Report expressions occurring in `do` and `mdo` blocks that appear to silently throw information away. For instance `do { mapM popInt xs ; return 10 }` would report the first statement in the `do` block as suspicious, as it has the type `StackM [Int]` and not `StackM ()`, but that `[Int]` value is not bound to anything. The warning is suppressed by explicitly mentioning in the source code that your program is throwing something away:

      do { _ <- mapM popInt xs ; return 10 }

  Of course, in this particular situation you can do even better:

      do { mapM_ popInt xs ; return 10 }

`-Wunused-type-patterns`

  Report all unused type variables which arise from patterns in type family and data family instances. For instance:

      type instance F x y = []

  would report `x` and `y` as unused. The warning is suppressed if the type variable name begins with an underscore, like so:

      type instance F _x _y = []

  Unlike `-Wunused-matches`, `-Wunused-type-patterns` is not implied by `-Wall`. The rationale for this decision is that unlike term-level pattern names, type names are often chosen expressly for documentation purposes, so using underscores in type names can make the documentation harder to read.

`-Wunused-foralls`

  Report all unused type variables which arise from explicit, user-written `forall` statements. For instance:

      g :: forall a b c. (b -> b)

  would report `a` and `c` as unused.

`-Wwrong-do-bind`

  Report expressions occurring in `do` and `mdo` blocks that appear to lack a binding. For instance `do { return (popInt 10) ; return 10 }` would report the first statement in the `do` block as suspicious, as it has the type `StackM (StackM Int)` (which consists of two nested applications of the same monad constructor), but which is not then “unpacked” by binding the result. The warning is suppressed by explicitly mentioning in the source code that your program is throwing something away:

      do { _ <- return (popInt 10) ; return 10 }

  For almost all sensible programs this will indicate a bug, and you probably intended to write:

      do { popInt 10 ; return 10 }

`-Winline-rule-shadowing`

  Warn if a rewrite RULE might fail to fire because the function might be inlined before the rule has a chance to fire. See How rules interact with INLINE/NOINLINE pragmas.

`-Wcpp-undef`

  Since: | 8.2

  This flag passes `-Wundef` to the C pre-processor (if its being used) which causes the pre-processor to warn on uses of the #if directive on undefined identifiers.

`-Wunbanged-strict-patterns`

  This flag warns whenever you write a pattern that binds a variable whose type is unlifted, and yet the pattern is not a bang pattern nor a bare variable. See Unboxed types for information about unlifted types.

`-Wmissing-home-modules`

  Since: | 8.2

  When a module provided by the package currently being compiled (i.e. the “home” package) is imported, but not explicitly listed in command line as a target. Useful for Cabal to ensure GHC won’t pick up modules, not listed neither in `exposed-modules`, nor in `other-modules`.

`-Wpartial-fields`

  Since: | 8.4

  The option `-Wpartial-fields` warns about record fields that could fail when accessed via a lacking constructor. The function `f` below will fail when applied to `Bar`, so the compiler will emit a warning at its definition when `-Wpartial-fields` is enabled.

  The warning is suppressed if the field name begins with an underscore.

      data Foo = Foo { f :: Int } | Bar

If you’re feeling really paranoid, the `-dcore-lint` option is a good choice. It turns on heavyweight intra-pass sanity-checking within GHC. (It checks GHC’s sanity, not yours.)