Lazy state monads, passing an updatable state through a computation. See below for examples.

Some computations may not require the full power of state transformers:

• For a read-only state, see Control.Monad.Trans.Reader.
• To accumulate a value without using it on the way, see Control.Monad.Trans.Writer.

In this version, sequencing of computations is lazy, so that for example the following produces a usable result:

evalState (sequence $ repeat $ do { n <- get; put (n*2); return n }) 1

For a strict version with the same interface, see Control.Monad.Trans.State.Strict.

Parser from ParseLib with Hugs:

type Parser a = StateT String [] a
   ==> StateT (String -> [(a,String)])

For example, item can be written as:

item = do (x:xs) <- get
       put xs
       return x

type BoringState s a = StateT s Identity a
     ==> StateT (s -> Identity (a,s))

type StateWithIO s a = StateT s IO a
     ==> StateT (s -> IO (a,s))

type StateWithErr s a = StateT s Maybe a
     ==> StateT (s -> Maybe (a,s))

A function to increment a counter. Taken from the paper "Generalising Monads to Arrows", John Hughes (http://www.cse.chalmers.se/~rjmh/), November 1998:

tick :: State Int Int
tick = do n <- get
          put (n+1)
          return n

Add one to the given number using the state monad:

plusOne :: Int -> Int
plusOne n = execState tick n

A contrived addition example. Works only with positive numbers:

plus :: Int -> Int -> Int
plus n x = execState (sequence $ replicate n tick) x

An example from The Craft of Functional Programming, Simon Thompson (http://www.cs.kent.ac.uk/people/staff/sjt/), Addison-Wesley 1999: "Given an arbitrary tree, transform it to a tree of integers in which the original elements are replaced by natural numbers, starting from 0. The same element has to be replaced by the same number at every occurrence, and when we meet an as-yet-unvisited element we have to find a 'new' number to match it with:"

data Tree a = Nil | Node a (Tree a) (Tree a) deriving (Show, Eq)
type Table a = [a]

numberTree :: Eq a => Tree a -> State (Table a) (Tree Int)
numberTree Nil = return Nil
numberTree (Node x t1 t2) = do
    num <- numberNode x
    nt1 <- numberTree t1
    nt2 <- numberTree t2
    return (Node num nt1 nt2)
  where
    numberNode :: Eq a => a -> State (Table a) Int
    numberNode x = do
        table <- get
        case elemIndex x table of
            Nothing -> do
                put (table ++ [x])
                return (length table)
            Just i -> return i

numTree applies numberTree with an initial state:

numTree :: (Eq a) => Tree a -> Tree Int
numTree t = evalState (numberTree t) []

testTree = Node "Zero" (Node "One" (Node "Two" Nil Nil) (Node "One" (Node "Zero" Nil Nil) Nil)) Nil
numTree testTree => Node 0 (Node 1 (Node 2 Nil Nil) (Node 1 (Node 0 Nil Nil) Nil)) Nil